GSP
Quick Navigator

Search Site

Unix VPS
A - Starter
B - Basic
C - Preferred
D - Commercial
MPS - Dedicated
Previous VPSs
* Sign Up! *

Support
Contact Us
Online Help
Handbooks
Domain Status
Man Pages

FAQ
Virtual Servers
Pricing
Billing
Technical

Network
Facilities
Connectivity
Topology Map

Miscellaneous
Server Agreement
Year 2038
Credits
 

USA Flag

 

 

Man Pages
FFI::Platypus::Record(3) User Contributed Perl Documentation FFI::Platypus::Record(3)

FFI::Platypus::Record - FFI support for structured records data

version 1.56

C:

 struct my_person {
   int         age;
   const char  title[3];
   const char *name
 };
 
 void process_person(struct my_person *person)
 {
   /* ... */
 }

Perl:

 package MyPerson;
 
 use FFI::Platypus::Record;
 
 record_layout_1(
   'int'       => 'age',
   'string(3)' => 'title',
   'string rw' => 'name',
 );
 
 package main;
 
 use FFI::Platypus 1.00;
 
 my $ffi = FFI::Platypus->new( api => 1 );
 $ffi->lib("myperson.so");
 $ffi->type("record(MyPerson)" => 'MyPerson');
 
 my $person = MyPerson->new(
   age   => 40,
   title => "Mr.",
   name  => "John Smith",
 );
 
 $ffi->attach( process_person => [ 'MyPerson*' ] => 'void' );
 
 process_person($person);
 
 $person->age($person->age + 1); # another year older
 
 process_person($person);

[version 0.21]

This module provides a mechanism for building classes that can be used to mange structured data records (known as C as "structs" and in some languages as "records"). A structured record is a series of bytes that have structure understood by the C or other foreign language library that you are interfacing with. It is designed for use with FFI and FFI::Platypus, though it may have other applications.

Before you get to deep into using this class you should also consider the FFI::C, which provides some overlapping functionality. Briefly, it comes down to this:

FFI::Platypus::Record
Supports:
C pointers to "struct" types
Passing C "struct"s by-value.

Does not support:

C "union" types.
C arrays of "struct" and "union" types.
FFI::C
Supports:
C "struct" and"union" types
C arrays of "struct" and "union" types.

Does not support:

Passing C "struct"s by-value.

String members are as of this writing a TODO for FFI::C, but should be coming soon!

 record_layout_1($ffi, $type => $name, ... );
 record_layout_1(\@ffi_args, $type => $name, ... );
 record_layout_1($type => $name, ... );

Define the layout of the record. You may optionally provide an instance of FFI::Platypus as the first argument in order to use its type aliases. Alternatively you may provide constructor arguments that will be passed to the internal platypus instance. Thus this is the same:

 my $ffi = FFI::Platypus->new( lang => 'Rust', api => 1 );
 record_layout_1( $ffi, ... );
 # same as:
 record_layout_1( [ lang => 'Rust' ], ... );

and this is the same:

 my $ffi = FFI::Platypus->new( api => 1 );
 record_layout_1( $ffi, ... );
 # same as:
 record_layout_1( ... );

Then you provide members as type/name pairs.

For each member you declare, "record_layout_1" will create an accessor which can be used to read and write its value. For example imagine a class "Foo":

 package Foo;
 
 use FFI::Platypus::Record;
 
 record_layout_1(
   int          => 'bar',  #  int bar;
   'string(10)' => 'baz',  #  char baz[10];
 );

You can get and set its fields with like named "bar" and "baz" accessors:

 my $foo = Foo->new;
 
 $foo->bar(22);
 my $value = $foo->bar;
 
 $foo->baz("grimlock\0\0"); # should be 10 characters long
 my $string_value = $foo->baz; # includes the trailing \0\0

You can also pass initial values in to the constructor, either passing as a list of key value pairs or by passing a hash reference:

 $foo = Foo->new(
   bar => 22,
   baz => "grimlock\0\0",
 );
 
 # same as:
 
 $foo = Foo->new( {
   bar => 22,
   baz => "grimlock\0\0",
 } );

If there are members of a record that you need to account for in terms of size and alignment, but do not want to have an accessor for, you can use ":" as a place holder for its name:

 record_layout_1(
   'int'        => ':',
   'string(10)' => 'baz',
 );

strings

So far I've shown fixed length strings. These are declared with the word "string" followed by the length of the string in parentheticals. Fixed length strings are included inside the record itself and do not need to be allocated or deallocated separately from the record. Variable length strings must be allocated on the heap, and thus require a sense of "ownership", that is whomever allocates variable length strings should be responsible for also free'ing them. To handle this, you can add a "ro" or "rw" trait to a string field. The default is "ro", means that you can get, but not set its value:

 package Foo;
 
 record_layout_1(
   'string ro' => 'bar',  # same type as 'string' and 'string_ro'
 );
 
 package main;
 
 my $foo = Foo->new;
 
 my $string = $foo->bar;  # GOOD
 $foo->bar("starscream"); # BAD

If you specify a field is "rw", then you can set its value:

 package Foo;
 
 record_layout_1(
   'string rw' => 'bar',  # same type as 'string_rw'
 );
 
 package main;
 
 my $foo = Foo->new;
 
 my $string = $foo->bar;  # GOOD
 $foo->bar("starscream"); # GOOD

Any string value that is pointed to by the record will be free'd when it falls out of scope, so you must be very careful that any "string rw" fields are not set or modified by C code. You should also take care not to copy any record that has a "rw" string in it because its values will be free'd twice!

 use Clone qw( clone );
 
 my $foo2 = clone $foo;  # BAD  bar will be free'd twice

arrays

Arrays of integer, floating points and opaque pointers are supported.

 package Foo;
 
 record_layout_1(
   'int[10]' => 'bar',
 );
 
 my $foo = Foo->new;
 
 $foo->bar([1,2,3,4,5,6,7,8,9,10]); # sets the values for the array
 my $list = $foo->bar;  # returns a list reference
 
 $foo->bar(5, -6); # sets the 5th element in the array to -6
 my $item = $foo->bar(5); gets the 5th element in the array

 record_layout($ffi, $type => $name, ... );
 record_layout(\@ffi_args, $type => $name, ... );
 record_layout($type => $name, ... );

This function works like "record_layout" except that "api => 0" is used instead of "api => 1". All new code should use "record_layout_1" instead.

These useful features (and probably more) are missing, and unlikely to be added.
Unions
Nested records

If you need these features, consider using FFI::C instead.

FFI::Platypus
The main platypus documentation.
FFI::C
Another interface for constructing structured data. It includes support for "union" and array types (which this module does not), but lacks support for passing records by-value.
FFI::Platypus::Record::TieArray
Tied array interface for record array members.
Convert::Binary::C
Another method for constructing and dissecting structured data records.
pack and unpack
Built-in Perl functions for constructing and dissecting structured data records.

Author: Graham Ollis <plicease@cpan.org>

Contributors:

Bakkiaraj Murugesan (bakkiaraj)

Dylan Cali (calid)

pipcet

Zaki Mughal (zmughal)

Fitz Elliott (felliott)

Vickenty Fesunov (vyf)

Gregor Herrmann (gregoa)

Shlomi Fish (shlomif)

Damyan Ivanov

Ilya Pavlov (Ilya33)

Petr Písař (ppisar)

Mohammad S Anwar (MANWAR)

Håkon Hægland (hakonhagland, HAKONH)

Meredith (merrilymeredith, MHOWARD)

Diab Jerius (DJERIUS)

Eric Brine (IKEGAMI)

szTheory

José Joaquín Atria (JJATRIA)

Pete Houston (openstrike, HOUSTON)

This software is copyright (c) 2015,2016,2017,2018,2019,2020 by Graham Ollis.

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

2021-10-28 perl v5.32.1

Search for    or go to Top of page |  Section 3 |  Main Index

Powered by GSP Visit the GSP FreeBSD Man Page Interface.
Output converted with ManDoc.