test_requires_git

    # skip all unless git is available as required
    test_requires_git version_ge => '1.6.5';

    # giving no operator implies 'version_ge'
    test_requires_git '1.6.5';

    # skip 2 if git is not available
  SKIP: {
        test_requires_git skip => 2;
        ...;
    }

    # skip 2 unless git is available as required
  SKIP: {
        test_requires_git
          skip       => 2,
          version_ge => '1.7.12';
        ...;
    }

    # skip all remaining tests if git is not available
    test_requires_git;

    # force which git binary to use
    test_requires_git
      git        => '/usr/local/bin/git',
      version_ge => '1.6.5';

Takes a list of version requirements (see "GIT VERSION CHECKING" below), and if one of them does not pass, skips all remaining tests. All conditions must be satisfied for the check to pass.

When the "skip" parameter is given, only the specified number of tests will be skipped.

The "current git" is obtained by running "git --version". I.e. the first "git" binary found in the current environment will be tested. This is of course sensitive to local changes to "PATH", so this will behave as expected:

    # skip 4 tests if there's no git available in the alternative PATH
  SKIP: {
        local $ENV{PATH} = $alternative_PATH;
        test_requires_git skip => 4;
        ...;
    }

When the "git" parameter is given, "test_requires_git" will run that program instead of "git".

If no condition is given, "test_requires_git" will simply check if "git" is available.

The first time it's called, "test_require_git" will print a test diagnostic with the output of "git --version" (if "git" is available, of course). To prevent this behaviour, load the module with:

    use Test::Requires::Git -quiet;

version_eq

    test_requires_git version_eq => $version;

Passes if the current git version is equal to $version.

version_ne

    test_requires_git version_eq => $version;

Passes if the current git version is not equal to $version.

version_lt

    test_requires_git version_lt => $version;

Passes if the current git version is less than $version.

version_gt

    test_requires_git version_gt => $version;

Passes if the current git version is greater than $version.

version_le

    test_requires_git version_le => $version;

Passes if the current git version is less than or equal $version.

version_ge

    test_requires_git version_ge => $version;

Passes if the current git version is greater than or equal $version.

As a special shortcut for the most common case, a lone version number is turned into a "version_ge" check, so the following two lines are exactly equivalent:

    test_requires_git version_ge => '1.6.5';

    # version_ge implied
    test_requires_git '1.6.5';