new

    my $arch = Archive::Tar::Wrapper->new();

Constructor for the "tar" wrapper class. Finds the "tar" executable by searching "PATH" and returning the first hit. In case you want to use a different tar executable, you can specify it as a parameter:

    my $arch = Archive::Tar::Wrapper->new(tar => '/path/to/tar');

Since Archive::Tar::Wrapper creates temporary directories to store "tar" data, the location of the temporary directory can be specified:

    my $arch = Archive::Tar::Wrapper->new(tmpdir => '/path/to/tmpdir');

Tremendous performance increases can be achieved if the temporary directory is located on a RAM disk. Check the "Using RAM Disks" in Archive::Tar::Wrapper section for details.

Additional options can be passed to the "tar" command by using the "tar_read_options" and "tar_write_options" parameters. Example:

     my $arch = Archive::Tar::Wrapper->new(
                   tar_read_options => 'p'
                );

will use "tar xfp archive.tgz" to extract the tarball instead of just "tar xf archive.tgz". GNU tar supports even more options, these can be passed in via

     my $arch = Archive::Tar::Wrapper->new(
                    tar_gnu_read_options => ["--numeric-owner"],
                );

Similarly, "tar_gnu_write_options" can be used to provide additional options for GNU tar implementations. For example, the tar object

    my $tar = Archive::Tar::Wrapper->new(
                  tar_gnu_write_options => ["--exclude=foo"],
              );

will call the "tar" utility internally like

    tar cf tarfile --exclude=foo ...

when the "write" method gets called.

By default, the "list_*()" functions will return only file entries: directories will be suppressed. To have "list_*()" return directories as well, use

     my $arch = Archive::Tar::Wrapper->new(
                   dirs  => 1
                );

If more files are added to a tarball than the command line can handle, Archive::Tar::Wrapper will switch from using the command

    tar cfv tarfile file1 file2 file3 ...

to

    tar cfv tarfile -T filelist

where "filelist" is a file containing all file to be added. The default for this switch is 512, but it can be changed by setting the parameter "max_cmd_line_args":

     my $arch = Archive::Tar::Wrapper->new(
         max_cmd_line_args  => 1024
     );

The expectable parameters are:

• tar
• tmpdir
• tar_read_options
• tar_write_options
• tar_gnu_read_options
• tar_gnu_write_options
• max_cmd_line_args: defaults to 512
• ramdisk

Returns a new instance of the class.

read

    $arch->read("archive.tgz");

"read()" opens the given tarball, expands it into a temporary directory and returns 1 on success or "undef" on failure. The temporary directory holding the tar data gets cleaned up when $arch goes out of scope.

"read" handles both compressed and uncompressed files. To find out if a file is compressed or uncompressed, it tries to guess by extension, then by checking the first couple of bytes in the tarfile.

If only a limited number of files is needed from a tarball, they can be specified after the tarball name:

    $arch->read("archive.tgz", "path/file.dat", "path/sub/another.txt");

The file names are passed unmodified to the "tar" command, make sure that the file paths match exactly what's in the tarball, otherwise "read()" will fail.

list_reset

    $arch->list_reset()

Resets the list iterator. To be used before the first call to "list_next()".

tardir

    $arch->tardir();

Return the directory the tarball was unpacked in. This is sometimes useful to play dirty tricks on Archive::Tar::Wrapper by mass-manipulating unpacked files before wrapping them back up into the tarball.

is_compressed

Expect as parameter a string with the path to the tarball.

Returns:

• a "z" character if the file is compressed with gzip.
• a "j" character if the file is compressed with bzip2.
• a "" character if the file is not compressed at all.

locate

    $arch->locate($logic_path);

Finds the physical location of a file, specified by $logic_path, which is the virtual path of the file within the tarball. Returns a path to the temporary file Archive::Tar::Wrapper created to manipulate the tarball on disk.

add

    $arch->add($logic_path, $file_or_stringref, [$options]);

Add a new file to the tarball. $logic_path is the virtual path of the file within the tarball. $file_or_stringref is either a scalar, in which case it holds the physical path of a file on disk to be transferred (i.e. copied) to the tarball, or it is a reference to a scalar, in which case its content is interpreted to be the data of the file.

If no additional parameters are given, permissions and user/group id settings of a file to be added are copied. If you want different settings, specify them in the options hash:

    $arch->add($logic_path, $stringref,
               { perm => 0755, uid => 123, gid => 10 });

If $file_or_stringref is a reference to a Unicode string, the "binmode" option has to be set to make sure the string gets written as proper UTF-8 into the tarfile:

    $arch->add($logic_path, $stringref, { binmode => ":utf8" });

perm_cp

Expects as parameters:

1.

string of the path to the file which permissions will be copied from.

2.

string of the path to the file which permissions will be copied to.

Returns 1 if everything works as expected.

perm_get

Expects as parameter the path to the source file.

Returns an array reference with only the permissions values, as returned by "stat".

perm_set

Expects as parameters:

1.

The path to the file where the permissions should be applied to.

2.

An array reference with the permissions (see "perm_set")

Returns 1 if everything goes fine.

Ignore errors here, as we can't change uid/gid unless we're the superuser (see LIMITATIONS section).

remove

    $arch->remove($logic_path);

Removes a file from the tarball. $logic_path is the virtual path of the file within the tarball.

list_all

    my $items = $arch->list_all();

Returns a reference to a (possibly huge) array of items in the tarfile. Each item is a reference to an array, containing two elements: the relative path of the item in the tarfile and the physical path to the unpacked file or directory on disk.

To iterate over the list, the following construct can be used:

    # Get a huge list with all entries
    for my $entry (@{$arch->list_all()}) {
        my($tar_path, $real_path) = @$entry;
        print "Tarpath: $tar_path Tempfile: $real_path\n";
    }

If the list of items in the tarfile is big, use "list_reset()" and "list_next()" instead of "list_all".

list_next

    my ($tar_path, $phys_path, $type) = $arch->list_next();

Returns the next item in the tarfile. It returns a list of three scalars: the relative path of the item in the tarfile, the physical path to the unpacked file or directory on disk, and the type of the entry (f=file, d=directory, l=symlink). Note that by default, Archive::Tar::Wrapper won't display directories, unless the "dirs" parameter is set when running the constructor.

write

    $arch->write($tarfile, $compress);

Write out the tarball by tarring up all temporary files and directories and store it in $tarfile on disk. If $compress holds a true value, compression is used.

is_gnu

    $arch->is_gnu();

Checks if the tar executable is a GNU tar by running 'tar --version' and parsing the output for "GNU".

Returns true or false (in Perl terms).

is_bsd

    $arch->is_bsd();

Same as "is_gnu()", but for BSD.

ramdisk_mount

It executes the "mount" program under the hood to mount a RAM disk.

Expects as parameter a hash with options to mount the RAM disk, like:

• size
• type (most probably "tmpfs")
• tmpdir

Returns 1 if everything goes fine.

Be sure to check the "Using RAM Disks" in Archive::Tar::Wrapper for full details on using RAM disks.

ramdisk_unmount

Don't expect parameters and returns 1 if everything goes fine.

Be sure to check the "Using RAM Disks" in Archive::Tar::Wrapper for full details on using RAM disks.

Microsoft Windows support

Versions below Windows 10 will not be supported for desktops, and for servers only Windows 2012 and above.

The GNU "tar.exe" program doesn't work properly with the current interface of Archive::Tar::Wrapper.

You must use the "bsdtar.exe" and make sure it appears first in the "PATH" environment variable than the GNU tar (if it is installed). See <http://libarchive.org/> for details about how to download and install "bsdtar.exe", or go to <http://gnuwin32.sourceforge.net/packages.html> for a direct download. Be sure to look for the "bzip2" program package to install it as well.

Windows 10 might come already with "bsdtar" program already installed. Please search for that on the appropriate page (Microsoft keeps changing the link to keep track of it here).

Having spaces in the path string to the tar program might be an issue too. Although there is some effort in terms of workaround it, you best might avoid it completely by installing in a different path than "C:\Program Files". Installing both "bsdtar" and "bzip2" in "C:\GnuWin32" will probably be enough when running the installers.