More backwards compatibility options with UTF-8 changes

"do_not_decode_query"

If true, then do not try to character decode any wide characters in your request URL query or keywords. Most readings of the relevant specifications suggest these should be UTF-* encoded, which is the default that Catalyst will use, however if you are creating a lot of URLs manually or have external evil clients, this might cause you trouble. If you find the changes introduced in Catalyst version 5.90080+ break some of your query code, you may disable the UTF-8 decoding globally using this configuration.

This setting takes precedence over "default_query_encoding" and "decode_query_using_global_encoding"

"default_query_encoding"

By default we decode query and keywords in your request URL using UTF-8, which is our reading of the relevant specifications. This setting allows one to specify a fixed value for how to decode your query. You might need this if you are doing a lot of custom encoding of your URLs and not using UTF-8.

This setting take precedence over "decode_query_using_global_encoding".

"decode_query_using_global_encoding"

Setting this to true will default your query decoding to whatever your general global encoding is (the default is UTF-8).

Catalyst::Plugin::Unicode::Encoding is now core

    package Myapp::Web;

    use Catalyst;

    __PACKAGE__->config( encoding => 'UTF-8' );

Please note that this is different from the old stand alone plugin which applied "UTF-8" encoding by default (that is, if you did not set an explicit "encoding" configuration value, it assumed you wanted UTF-8). In order to preserve backwards compatibility you will need to explicitly turn it on via the configuration setting. THIS MIGHT CHANGE IN THE FUTURE, so please consider starting to test your application with proper UTF-8 support and remove all those crappy hacks you munged into the code because you didn't know the Plugin existed :)

For people that are using the Plugin, you will note a startup warning suggesting that you can remove it from the plugin list. When you do so, please remember to add the configuration setting, since you can no longer rely on the default being UTF-8. We'll add it for you if you continue to use the stand alone plugin and we detect this, but this backwards compatibility shim will likely be removed in a few releases (trying to clean up the codebase after all).

If you have trouble with any of this, please bring it to the attention of the Catalyst maintainer group.

basic async and event loop support

We consider this feature experimental. We will try not to break it, but we reserve the right to make necessary changes to fix major issues that people run into when the use this functionality in the wild.

Regex dispatch type is deprecated.

You are encouraged to move your application to Chained dispatch (Catalyst::DispatchType::Chained).

If you cannot do so, please add a dependency to Catalyst::DispatchType::Regex to your application's Makefile.PL

Upgrading the FastCGI Engine

Upgrading the mod_perl / Apache Engines

Catalyst::Engine::Apache2::MP19, however, is no longer supported, as Plack does not support mod_perl version 1.99. This is unlikely to be a problem for anyone, as 1.99 was a brief beta-test release for mod_perl 2, and all users of mod_perl 1.99 are encouraged to upgrade to a supported release of Apache 2 and mod_perl 2.

Upgrading the HTTP Engine

Upgrading the CGI Engine

Upgrading Catalyst::Engine::HTTP::Prefork

You can regenerate your "myapp_server.pl" script with "catalyst.pl" and implement a "MyApp::Script::Server" class that looks like this:

    package MyApp::Script::Server;
    use Moose;
    use namespace::autoclean;

    extends 'CatalystX::Script::Server::Starman';

    1;

This takes advantage of the new script system, and will add a number of options to the standard server script as extra options are added by Starman.

More information about these options can be seen at "SYNOPSIS" in CatalystX::Script::Server::Starman.

An alternate route to implement this functionality is to write a simple .psgi file for your application, and then use the plackup utility to start the server.

Upgrading the PSGI Engine

Applications that were using Catalyst::Engine::PSGI previously should entirely continue to work in this release with no changes.

However, if you have an "app.psgi" script, then you no longer need to specify the PSGI engine. Instead, the Catalyst application class now has a new method "psgi_app" which returns a PSGI compatible coderef which you can wrap in the middleware of your choice.

Catalyst will use the .psgi for your application if it is located in the "home" directory of the application.

For example, if you were using Catalyst::Engine::PSGI in the past, you will have written (or generated) a "script/myapp.psgi" file similar to this one:

    use Plack::Builder;
    use MyCatalytApp;

    MyCatalystApp->setup_engine('PSGI');

    builder {
        enable ... # enable your desired middleware
        sub { MyCatalystApp->run(@_) };
    };

Instead, you now say:

    use Plack::Builder;
    use MyCatalystApp;

    builder {
        enable ... #enable your desired middleware
        MyCatalystApp->psgi_app;
    };

In the simplest case:

    MyCatalystApp->setup_engine('PSGI');
    my $app = sub { MyCatalystApp->run(@_) }

becomes

    my $app = MyCatalystApp->psgi_app(@_);

NOT:

    my $app = sub { MyCatalystApp->psgi_app(@_) };
    # If you make ^^ this mistake, your app won't work, and will confuse the hell out of you!

You can now move "script/myapp.psgi" to "myapp.psgi", and the built-in Catalyst scripts and your test suite will start using your .psgi file.

NOTE: If you rename your .psgi file without these modifications, then any tests run via Catalyst::Test will not be compatible with the new release, and will result in the development server starting, rather than the expected test running.

NOTE: If you are directly accessing "$c->req->env" to get the PSGI environment then this accessor is moved to "$c->engine->env", you will need to update your code.

Engines which are known to be broken

Catalyst::Engine::Wx

Catalyst::Engine::Zeus

Catalyst::Engine::JobQueue::POE

Catalyst::Engine::XMPP2

Catalyst::Engine::SCGI

Engines with unknown status

Catalyst::Engine::Mojo

Catalyst::Engine::Server (marked as Deprecated)

Catalyst::Engine::HTTP::POE (marked as Deprecated)

Plack functionality

Tests in 5.9

Previously, if using Catalyst::Test and doing local requests (against a local server), if the application threw an exception then this exception propagated into the test.

This behavior has been removed, and now a 500 response will be returned to the test. This change standardizes behavior, so that local test requests behave similarly to remote requests.

Application class roles

See Catalyst::Manual::ExtendingCatalyst for more information about using Moose in your applications.

Controller actions in Moose roles

Using Moose in Components

    package TestApp::Controller::Root;
    use Moose;
    BEGIN { extends 'Catalyst::Component' }; # Or ::Controller, or whatever

See "Components which inherit from Moose::Object before Catalyst::Component".

Applications in a single file

This is due to the fact that Catalyst is inlining a new method on your application class allowing it to be compatible with Moose. The method used to do this changed in 5.80004 to avoid the possibility of reporting an 'Unknown Error' if your application failed to compile.

Issues with Class::C3

This issue manifests itself by your application failing to start due to an error message about having a non-linear @ISA.

The Catalyst plugin most often causing this is Catalyst::Plugin::Session::Store::FastMmap - if you are using this plugin and see issues, then please upgrade your plugins, as it has been fixed. Note that Makefile.PL in the distribution will warn about known incompatible components.

This issue can, however, be found in your own application - the only solution is to go through each base class of the class the error was reported against, until you identify the ones in conflict, and resolve them.

To be able to generate a linear @ISA, the list of superclasses for each class must be resolvable using the C3 algorithm. Unfortunately, when superclasses are being used as mixins (to add functionality used in your class), and with multiple inheritance, it is easy to get this wrong.

Most common is the case of:

    package Component1; # Note, this is the common case
    use base qw/Class::Accessor::Fast Class::Data::Inheritable/;

    package Component2; # Accidentally saying it this way causes a failure
    use base qw/Class::Data::Inheritable Class::Accessor::Fast/;

    package GoesBang;
    use base qw/Component1 Component2/;

Any situation like this will cause your application to fail to start.

For additional documentation about this issue, and how to resolve it, see Class::C3::Adopt::NEXT.

Components which inherit from Moose::Object before Catalyst::Component

    package TestApp::Controller::Example;
    use Moose;
    extends qw/Moose::Object Catalyst::Component/;

to use the constructor provided by Moose, while working (if you do some hacks with the " BUILDARGS " method), will not work with Catalyst 5.80 as "Catalyst::Component" inherits from "Moose::Object", and so @ISA fails to linearize.

The correct way to use Moose in a component in a both forward and backwards compatible way is:

    package TestApp::Controller::Root;
    use Moose;
    BEGIN { extends 'Catalyst::Component' }; # Or ::Controller, or whatever

Note that the " extends " declaration needs to occur in a begin block for attributes to operate correctly.

This way you do not inherit directly from "Moose::Object" yourself. Having components which do not inherit their constructor from "Catalyst::Component" is unsupported, and has never been recommended, therefore you're on your own if you're using this technique. You'll need to detect the version of Catalyst your application is running, and deal with it appropriately.

You also don't get the Moose::Object constructor, and therefore attribute initialization will not work as normally expected. If you want to use Moose attributes, then they need to be made lazy to correctly initialize.

Note that this only applies if your component needs to maintain component backwards compatibility for Catalyst versions before 5.71001 - in 5.71001 attributes work as expected, and the BUILD method is called normally (although BUILDARGS is not).

If you depend on Catalyst 5.8, then all Moose features work as expected.

You will also see this issue if you do the following:

    package TestApp::Controller::Example;
    use Moose;
    use base 'Catalyst::Controller';

as " use base " appends to @ISA.

use Moose in MyApp

Similar to the above, this will also fail:

    package MyApp;
    use Moose;
    use Catalyst qw/
      ConfigLoader
    /;
    __PACKAGE__->setup;

If you need to use Moose in your application class (e.g. for method modifiers etc.) then the correct technique is:

    package MyApp;
    use Moose;
    use Catalyst;

    extends 'Catalyst';

    __PACKAGE__->config( name => 'MyApp' );
    __PACKAGE__->setup(qw/
        ConfigLoader
    /);

Anonymous closures installed directly into the symbol table

    # Original code, likely to break:
    my $full_method_name = join('::', $package_name, $method_name);
    *$full_method_name = sub { ... };

    # Fixed Code
    use Sub::Name 'subname';
    my $full_method_name = join('::',$package_name, $method_name);
    *$full_method_name = subname $full_method_name, sub { ... };

Additionally, you can take advantage of Catalyst's use of Class::MOP and install the closure using the appropriate metaclass. Example:

    use Class::MOP;
    my $metaclass = Moose::Meta::Class->initialize($package_name);
    $metaclass->add_method($method_name => sub { ... });

Hooking into application setup

    sub setup {
        my ($class, @args) = @_;
        $class->NEXT::setup(@args);
        ... # things to do after the actual setup
    }

With Catalyst 5.80 this won't work anymore, because Catalyst no longer uses NEXT.pm for method resolution. The functionality was only ever originally operational as NEXT remembers what methods have already been called, and will not call them again.

Using this now causes infinite recursion between MyApp::setup and Catalyst::setup, due to other backwards compatibility issues related to how plugin setup works. Moose method modifiers like "before|after|around setup => sub { ... };" also will not operate correctly on the setup method.

The right way to do it is this:

    after setup_finalize => sub {
        ... # things to do after the actual setup
    };

The setup_finalize hook was introduced as a way to avoid this issue.

Components with a new method which returns false

This behavior makes no sense, and so has been removed. Implementing your own " new " method in components is highly discouraged. Instead, you should inherit the new method from Catalyst::Component, and use Moose's BUILD functionality and/or Moose attributes to perform any construction work necessary for your class.

__PACKAGE__->mk_accessor('meta');

Class::Data::Inheritable side effects

This behavior has been removed. While the class data is still stored per-class, it is stored on the metaclass of the class defining the accessor.

Therefore anything relying on the side effect of the accessor being copied down will be broken.

The following test demonstrates the problem:

    {
        package BaseClass;
        use base qw/Class::Data::Inheritable/;
        __PACKAGE__->mk_classdata('foo');
    }

    {
        package Child;
        use base qw/BaseClass/;
    }

    BaseClass->foo('base class');
    Child->foo('sub class');

    use Test::More;
    isnt(BaseClass->can('foo'), Child->can('foo'));

Extending Catalyst::Request or other classes in an ad hoc manner using mk_accessors

This is no longer supported - users should make a subclass of the class whose behavior they would like to change, rather than globally polluting the Catalyst objects.

Confused multiple inheritance with Catalyst::Component::COMPONENT

If a COMPONENT method is detected in the inheritance hierarchy to the right hand side of Catalyst::Component::COMPONENT, then the following warning message will be emitted:

    There is a COMPONENT method resolving after Catalyst::Component
    in ${next_package}.

The correct fix is to re-arrange your class's inheritance hierarchy so that the COMPONENT method you would like to inherit is the first (left-hand most) COMPONENT method in your @ISA.

Development server relying on environment variables

Actions in your application class

This warning, also affects tests. You should move actions in your test, creating a myTest::Controller::Root, like the following example:

    package MyTest::Controller::Root;

    use strict;
    use warnings;

    use parent 'Catalyst::Controller';

    __PACKAGE__->config(namespace => '');

    sub action : Local {
        my ( $self, $c ) = @_;
        $c->do_something;
    }

    1;

::[MVC]:: naming scheme

This is still supported, but it is recommended that you rename your application components to Model/View/Controller.

A warning will be issued at application startup if the ::[MVC]:: naming scheme is in use.

Catalyst::Base

Methods in Catalyst::Dispatcher

tree

dispatch_types

registered_dispatch_types

method_action_class

action_hash

container_hash

The first time one of these methods is called, a warning will be emitted:

    Class $class is calling the deprecated method Catalyst::Dispatcher::$public_method_name,
    this will be removed in Catalyst 5.9

You should NEVER be calling any of these methods from application code.

Plugin authors and maintainers whose plugins currently call these methods should change to using the public API, or, if you do not feel the public API adequately supports your use case, please email the development list to discuss what API features you need so that you can be appropriately supported.

Class files with names that don't correspond to the packages they define

    require $class was successful but the package is not defined.

This is to protect against confusing bugs caused by mistyping package names, and will become a fatal error in a future version.

Please note that 'inner packages' (via Devel::InnerPackage) are still fully supported; this warning is only issued when component file naming does not map to any of the packages defined within that component.

$c->plugin method

Instead you are recommended to use Catalyst::Model::Adaptor or similar to compose the functionality you need outside of the main application name space.

Calling the plugin method will not be supported past Catalyst 5.81.