import

This performs argument parsing ready for calling create_methods. In particular, this is the point at which v1 & v2 calls are distinguished.

This is implicitly called as part of a "use" statement:

  use Class::MethodMaker
    [ scalar => [qw/ foo bar baz /],
      new    => [qw/ new /]        ,
    ];

is equivalent to

  Class::MethodMaker->import([scalar => [qw/ foo bar baz /],
                              new    => [qw/ new /]        ,
                             ]);

See perldoc -f use for details of this equivalence.

The methods created are installed into the class calling the import - or more accurately, the first class up the calling stack that is not "Class::MethodMaker" or a subclass thereof.

SYNOPSIS

  Class::MethodMaker->import([scalar => [+{ -type   => 'File::Stat',
                                            -forward => [qw/ mode size /],
                                            '*_foo' => '*_fig',
                                            '*_gop' => undef,
                                            '*_bar' => '*_bar',
                                            '*_hal' => '*_sal',
                                           },
                                         qw/ -static bob /,
                                        ]
                             ]);
    

parse_options

Parse the arguments given to import and call create_methods appropriately. See main text for options syntax.

SYNOPSIS

  Class::MethodMaker->parse_options('TargetClass',
                                    [scalar =>
                                      [{ -type => 'File::stat',
                                         -forward => [qw/ mode
                                                          size /],
                                         '*_foo' => '*_fig',
                                         '*_gop' => undef,
                                         '*_bar' => '*_bar',
                                         '*_hal' => '*_sal',
                                       },
                                       qw( -static bob ),
                                      ]])},
  Class::MethodMaker->parse_options('TargetClass2',
                                    [scalar =>
                                      ['baz',
                                       { -type => 'File::stat',
                                         -forward => [qw/ mode
                                                          size /],
                                         '*_foo' => '*_fog',
                                         '*_bar' => '*_bar',
                                         '*_hal' => '*_sal',
                                       },
                                       qw( -static bob ),
                                      ]],
                                    +{ -type => 'Math::BigInt', },
                                    +{'*_foo' => '*_fig',
                                      '*_gop' => undef,},
                                   )},
    

ARGUMENTS

create_methods

Add methods to a class. Methods for multiple components may be added this way, but create_methods handles only one set of options. parse_options is responsible for sorting which options to apply to which components, and calling create_methods appropriately.

SYNOPSIS

  Class::MethodMaker->create_methods($target_class,
                                     scalar => bob,
                                     +{ static => 1,
                                        type   => 'File::Stat',
                                        forward => [qw/ mode size /], },
                                     +{ '*_foo' => '*_fig',
                                        '*_gop' => undef,
                                        '*_bar' => '*_bar',
                                        '*_hal' => '*_sal', }
                                    );
    

ARGUMENTS

install_methods

SYNOPSIS

  Class::MethodMaker->install_methods
    ($classname, { incr => sub { $i++ },
                   decr => sub { $i-- },
                 }
    );
    

ARGUMENTS

new

  use Class::MethodMaker
    [ new => 'new' ];

Creates a basic constructor.

Takes a single string or a reference to an array of strings as its argument. For each string creates a simple method that creates and returns an object of the appropriate class.

The generated method may be called as a class method, as usual, or as in instance method, in which case a new object of the same class as the instance will be created.

Options

-hash

The constructor will accept as arguments a list of pairs, from component name to initial value. For each pair, the named component is initialized by calling the method of the same name with the given value. E.g.,

  package MyClass;
  use Class::MethodMaker
    [ new    => [qw/ -hash new /],
      scalar => [qw/ b c /],
    ];
  sub d {
    my $self = shift;
    $self->{d} = $_[0]
      if @_;
    return $self->{d};
  }
  package main;
  # The statement below implicitly calls
  # $m->b(1); $m->c(2); $m->d(3)
  # on the newly constructed m.
  my $m = MyClass->new(b => 1, c => 2, d => 3);
    

Note that this can also call user-supplied methods that have the name of the component.

Instead of a list of pairs, a single hashref may also be passed, which will be expanded appropriately. So the above is equivalent to:

  my $m = MyClass->new({ b => 1, c => 2, d => 3 });
    

Advanced Users: Class::MethodMaker method renaming is taken into account, so even if the "*" method is renamed or removed, this will still work.

-init

This option causes the new method to call an initializer method. The method is called "init" (original, eh?) by default, but the option may be given an alternative value. The init method is passed any arguments that were passed to the constructor, but the method is invoked on the newly constructed instance.

  use Class::MethodMaker
    [ new => [qw/ -init new1 /, { -init => 'bob' } => 'init2' ]];
    

Constructing with new1 involves an implicit call to "init", whilst constructing with new2 involves an implicit call to "bob" (instead of "init").

It is the responsibility of the user to ensure that an "init" method (or whatever name) is defined.

-singleton

Creates a basic constructor which only ever returns a single instance of the class: i.e., after the first call, repeated calls to this constructor return the same instance. Note that the instance is instantiated at the time of the first call, not before.

abstract

  use Class::MethodMaker
    [ abstract => [ qw / foo bar baz / ] ];

This creates a number of methods that will die if called. This is intended to support the use of abstract methods, that must be overridden in a useful subclass.

copy

  use Class::MethodMaker
    [ copy => [qw/ shallow -deep deep /] ];

This creates method that produce a copy of self. The copy is a by default a shallow copy; any references will be shared by the instance upon which the method is called and the returned newborn. One option is taken, "-deep", which causes the method to create deep copies instead (i.e., references are copied recursively).

Implementation Note:

Deep copies are performed using the "Storable" module if available, else "Data::Dumper". The "Storable" module is liable to be much quicker. However, this implementation note is not an API specification: the implementation details are open to change in a future version as faster/better ways of performing a deep copy become available.

Note that deep copying does not currently support the copying of coderefs, ties or XS-based objects.