NAME

SYNOPSIS

  use DBI;

  my $dsn = "DBI:MariaDB:database=$database;host=$hostname;port=$port";
  my $dbh = DBI->connect($dsn, $user, $password);

  my $sth = $dbh->prepare(
      'SELECT id, first_name, last_name FROM authors WHERE last_name = ?'
  ) or die 'prepare statement failed: ' . $dbh->errstr();
  $sth->execute('Eggers') or die 'execution failed: ' . $dbh->errstr();
  print $sth->rows() . " rows found.\n";
  while (my $ref = $sth->fetchrow_hashref()) {
      print "Found a row: id = $ref->{'id'}, fn = $ref->{'first_name'}\n";
  }

EXAMPLE

  #!/usr/bin/perl

  use strict;
  use warnings;
  use DBI;

  # Connect to the database.
  my $dbh = DBI->connect('DBI:MariaDB:database=test;host=localhost',
                         'joe', q(joe's password),
                         { RaiseError => 1, PrintError => 0 });

  # Drop table 'foo'. This may fail, if 'foo' doesn't exist
  # Thus we put an eval around it.
  eval {
      $dbh->do('DROP TABLE foo');
  } or do {
      print 'Dropping foo failed: ' . $dbh->errstr() . "\n";
  };

  # Create a new table 'foo'. This must not fail, thus we don't
  # catch errors.
  $dbh->do('CREATE TABLE foo (id INTEGER, name VARCHAR(20))');

  # INSERT some data into 'foo' using placeholders
  $dbh->do('INSERT INTO foo VALUES (?, ?)', undef, 2, 'Jochen');

  # now retrieve data from the table.
  my $sth = $dbh->prepare('SELECT * FROM foo');
  $sth->execute();
  while (my $ref = $sth->fetchrow_hashref()) {
      print "Found a row: id = $ref->{'id'}, name = $ref->{'name'}\n";
  }

  # Disconnect from the database.
  $dbh->disconnect();

DESCRIPTION

In what follows we first discuss the use of DBD::MariaDB, because this is what you will need the most. For installation, see the separate document DBD::MariaDB::INSTALL. See "EXAMPLE" for a simple example above.

From perl you activate the interface with the statement

  use DBI;

After that you can connect to multiple MariaDB and MySQL database servers and send multiple queries to any of them via a simple object oriented interface. Two types of objects are available: database handles and statement handles. Perl returns a database handle to the connect method like so:

  my $dbh = DBI->connect("DBI:MariaDB:database=$db;host=$host",
                         $user, $password,
                         { RaiseError => 1, PrintError => 0 });

Once you have connected to a database, you can execute SQL statements with:

  $dbh->do('INSERT INTO foo VALUES (?, ?)', undef, $number, $name);

See DBI do method for details. See also the bind_param method in DBI. See "DATABASE HANDLES" below for more details on database handles.

If you want to retrieve results, you need to create a so-called statement handle with:

  my $sth = $dbh->prepare('SELECT * FROM ' . $dbh->quote_identifier($table));
  $sth->execute();

This statement handle can be used for multiple things. First of all you can retrieve a row of data:

  my $row = $sth->fetchrow_hashref();

If your table has columns "ID" and "NAME", then $row will be hash ref with keys "ID" and "NAME". See "STATEMENT HANDLES" below for more details on statement handles.

But now for a more formal approach:

DATABASE HANDLES

  my $errno = $dbh->{'mariadb_errno'};
  my $error = $dbh->{'mariadb_error'};
  my $hostinfo = $dbh->{'mariadb_hostinfo'};
  my $info = $dbh->{'mariadb_info'};
  my $insertid = $dbh->{'mariadb_insertid'};
  my $protoinfo = $dbh->{'mariadb_protoinfo'};
  my $serverinfo = $dbh->{'mariadb_serverinfo'};
  my $ssl_cipher = $dbh->{'mariadb_ssl_cipher'};
  my $stat = $dbh->{'mariadb_stat'};
  my $thread_id = $dbh->{'mariadb_thread_id'};

These correspond to "mysql_errno()", "mysql_error()", "mysql_get_host_info()", "mysql_info()", "mysql_insert_id()", "mysql_get_proto_info()", "mysql_get_server_info()", "mysql_stat()", "mysql_get_ssl_cipher()" and "mysql_thread_id()" respectively.

Portable DBI applications should not use them. Instead they should use standard DBI methods: "$dbh->err()" and "$dbh->errstr()" for error number and string, "$dbh->get_info($GetInfoType{SQL_SERVER_NAME})" for server host name, "$dbh->get_info($GetInfoType{SQL_DBMS_NAME})" and "$dbh->get_info($GetInfoType{SQL_DBMS_VER})" for server database name and version, "$dbh->last_insert_id()" or "$sth->last_insert_id()" for insert id.

mariadb_clientinfo

mariadb_clientversion

List information of the MariaDB or MySQL client library that DBD::MariaDB was built against:

  print "$dbh->{mariadb_clientinfo}\n";

  5.2.0-MariaDB

  print "$dbh->{mariadb_clientversion}\n";

  50200
    

Portable DBI applications should not be interested in version of underlying client library. DBD::MariaDB is there to hide any possible incompatibility and works correctly with any available version.

mariadb_serverversion

  print "$dbh->{mariadb_serverversion}\n";

  50200
    

Portable DBI applications should use "$dbh->get_info($GetInfoType{SQL_DBMS_NAME})" and "$dbh->get_info($GetInfoType{SQL_DBMS_VER})" for server database name and version instead.

mariadb_ssl_cipher

Returns the SSL encryption cipher used for the given connection to the server. In case SSL encryption was not enabled with mariadb_ssl or was not established returns "undef".

  my $ssl_cipher = $dbh->{mariadb_ssl_cipher};
  if (defined $ssl_cipher) {
      print "Connection with server is encrypted with cipher: $ssl_cipher\n";
  } else {
      print "Connection with server is not encrypted\n";
  }
    

mariadb_dbd_stats

  my $info_hashref = $dbh->{mariadb_dbd_stats};
    

DBD::MariaDB keeps track of some statistics in the mariadb_dbd_stats attribute. The following stats are being maintained:

The DBD::MariaDB driver also supports the following attributes of database handles (read/write):

mariadb_auto_reconnect

This attribute determines whether DBD::MariaDB will automatically reconnect to MariaDB or MySQL server if the connection be lost. This feature defaults to off. Setting mariadb_auto_reconnect to 1 is not advised if "LOCK TABLES" is used because if DBD::MariaDB reconnect to MariaDB or MySQL server all table locks will be lost. This attribute is ignored when AutoCommit is turned off, and when AutoCommit is turned off, DBD::MariaDB will not automatically reconnect to the server.

It is also possible to set the default value of the mariadb_auto_reconnect attribute for the $dbh by passing it in the "\%attr" hash for "DBI->connect".

  $dbh->{mariadb_auto_reconnect} = 1;
    

or

  my $dbh = DBI->connect($dsn, $user, $password, {
      mariadb_auto_reconnect => 1,
  });
    

Note that if you are using a module or framework that performs reconnections for you (for example DBIx::Connector in fixup mode), this value must be set to 0.

mariadb_use_result

This attribute forces the driver to use "mysql_use_result()" rather than "mysql_store_result()" library function. The former is faster and less memory consuming, but tends to block other processes. "mysql_store_result()" is the default due to that fact storing the result is expected behavior with most applications.

It is possible to set the default value of the mariadb_use_result attribute for the $dbh via the DSN:

  my $dbh = DBI->connect('DBI:MariaDB:test;mariadb_use_result=1', $user, $pass);
    

You can also set it after creation of the database handle:

  $dbh->{mariadb_use_result} = 0; # disable
  $dbh->{mariadb_use_result} = 1; # enable
    

You can also set or unset the mariadb_use_result setting on your statement handle, when creating the statement handle or after it has been created. See "STATEMENT HANDLES".

mariadb_bind_type_guessing

This attribute causes the driver (emulated prepare statements) to attempt to guess if a value being bound is a numeric value, and if so, doesn't quote the value. This was created by Dragonchild and is one way to deal with the performance issue of using quotes in a statement that is inserting or updating a large numeric value.

CAVEAT: Even though you can insert an integer value into a character column, if this column is indexed, if you query that column with the integer value not being quoted, it will not use the index:

  MariaDB [test]> explain select * from test where value0 = '3' \G
  *************************** 1. row ***************************
             id: 1
    select_type: SIMPLE
          table: test
           type: ref
  possible_keys: value0
            key: value0
        key_len: 13
            ref: const
           rows: 1
          Extra: Using index condition
  1 row in set (0.00 sec)

  MariaDB [test]> explain select * from test where value0 = 3
      -> \G
  *************************** 1. row ***************************
             id: 1
    select_type: SIMPLE
          table: test
           type: ALL
  possible_keys: value0
            key: NULL
        key_len: NULL
            ref: NULL
           rows: 6
          Extra: Using where
  1 row in set (0.00 sec)
    

See bug: <https://rt.cpan.org/Public/Bug/Display.html?id=43822>

mariadb_bind_type_guessing can be turned on via

- through DSN

  my $dbh = DBI->connect('DBI:MariaDB:test', 'username', 'pass', {
      mariadb_bind_type_guessing => 1
  });
    

- OR after handle creation

  $dbh->{mariadb_bind_type_guessing} = 1;
    

mariadb_bind_comment_placeholders

This attribute causes the driver (emulated prepare statements) will cause any placeholders in comments to be bound. This is not correct prepared statement behavior, but some developers have come to depend on this behavior.

mariadb_no_autocommit_cmd

This attribute causes the driver to not issue "SET AUTOCOMMIT" either through explicit or using "mysql_autocommit()". This is particularly useful in the case of using MySQL Proxy.

See the bug report: <https://rt.cpan.org/Public/Bug/Display.html?id=46308>

mariadb_no_autocommit_cmd can be turned on when creating the database handle:

  my $dbh = DBI->connect('DBI:MariaDB:test', 'username', 'pass', {
      mariadb_no_autocommit_cmd => 1
  });
    

or using an existing database handle:

  $dbh->{mariadb_no_autocommit_cmd} = 1;
    

mariadb_max_allowed_packet

This attribute controls the maximum size of one packet, any generated or intermediate string and any bind parameter. Default value depends on client MariaDB/MySQL library and should be 1GB.

  $dbh->{mariadb_max_allowed_packet} = 32*1024*1024; # limit max size to 32MB
    

Documentation for some DBD::MariaDB methods of database handles:

ping

This can be used to send a ping to the server. See DBI ping.

  my $rc = $dbh->ping();
    

get_info

This method can be used to retrieve information about MariaDB or MySQL server. See DBI get_info. Some useful information: "SQL_DBMS_NAME" returns server database name, either "MariaDB" or "MySQL". "SQL_DBMS_VER" returns server database version and "SQL_SERVER_NAME" returns server host name.

  use DBI::Const::GetInfoType;

  print $dbh->get_info($GetInfoType{SQL_DBMS_NAME});

  MariaDB

  print $dbh->get_info($GetInfoType{SQL_DBMS_VER});

  10.01.2600

  print $dbh->get_info($GetInfoType{SQL_SERVER_NAME});

  Localhost via UNIX socket
    

STATEMENT HANDLES

  my $numFields = $sth->{NUM_OF_FIELDS};

Note, that most attributes are valid only after a successful execute. An "undef" value will returned otherwise. The most important exception is the mariadb_use_result attribute.

To set the mariadb_use_result attribute on statement handle $sth, use either of the following:

  my $sth = $dbh->prepare($sql, { mariadb_use_result => 1});

or

  my $sth = $dbh->prepare($sql);
  $sth->{mariadb_use_result} = 1;

Column dependent attributes, for example NAME, the column names, are returned as a reference to an array. The array indices are corresponding to the indices of the arrays returned by fetchrow and similar methods. For example the following code will print a header of table names together with all rows:

  my $sth = $dbh->prepare('SELECT * FROM t')
      or die 'Error: ' . $dbh->errstr() . "\n";

  $sth->execute()
      or die 'Error: ' . $sth->errstr() . "\n";

  my $names = $sth->{NAME};
  my $numFields = $sth->{'NUM_OF_FIELDS'} - 1;
  for my $i ( 0..$numFields ) {
      printf('%s%s', $i ? ',' : '', $$names[$i]);
  }
  print "\n";
  while (my $ref = $sth->fetchrow_arrayref()) {
      for my $i ( 0..$numFields ) {
          printf('%s%s', $i ? ',' : '', $$ref[$i]);
      }
      print "\n";
  }

For portable applications you should restrict yourself to attributes with capitalized or mixed case names. Lower case attribute names are private to DBD::MariaDB. The attribute list includes:

ChopBlanks

This attribute determines whether a fetchrow will chop preceding and trailing blanks off the column values. Chopping blanks does not have impact on the mariadb_max_length attribute.

mariadb_insertid

If the statement you executed performs an "INSERT", and there is an "AUTO_INCREMENT" column in the table you inserted in, this attribute holds the value stored into the "AUTO_INCREMENT" column, if that value is automatically generated, by storing "NULL" or 0 or was specified as an explicit value.

Typically, you'd access the value via "$sth->{mariadb_insertid}". The value can also be accessed via "$dbh->{mariadb_insertid}" but this can easily produce incorrect results in case one database handle is shared.

Portable DBI applications should not use mariadb_insertid. Instead they should use DBI method "$dbh->last_insert_id()" or statement DBI method "$sth->last_insert_id()". Statement method was introduced in DBI version 1.642, but DBD::MariaDB implements it also for older DBI versions.

mariadb_is_blob

Reference to an array of boolean values; Logical true value indicates, that the respective column is a blob.

mariadb_is_key

Reference to an array of boolean values; Logical true value indicates, that the respective column is a key.

mariadb_is_num

Reference to an array of boolean values; Logical true value indicates, that the respective column contains numeric values.

mariadb_is_pri_key

Reference to an array of boolean values; Logical true value indicates, that the respective column is a primary key.

mariadb_is_auto_increment

Reference to an array of boolean values; Logical true value indicates that the respective column is an "AUTO_INCREMENT" column.

mariadb_length

mariadb_max_length

A reference to an array of maximum column sizes. The mariadb_max_length is the maximum physically present in the result table, mariadb_length gives the theoretically possible maximum.

For string orientated variable types (char, varchar, text and similar types) both attributes return value in bytes. If you are interested in number of characters then instead of mariadb_length use "COLUMN_SIZE" via standard DBI method column_info and instead of mariadb_max_length issue SQL query "SELECT MAX(CHAR_LENGTH(...))". Example:

  my $ci_sth = $dbh->column_info(undef, undef, $table, $column);
  my $ci_ref = $ci_sth->fetchall_arrayref({});
  my $mariadb_char_length = $ci_ref->[0]->{COLUMN_SIZE};

  my $mariadb_char_max_length = $dbh->selectrow_array(sprintf(
                                    'SELECT MAX(CHAR_LENGTH(%s)) FROM %s',
                                    $dbh->quote_identifier($column),
                                    $dbh->quote_identifier($table),
                                ));
    

NAME

A reference to an array of column names.

NULLABLE

A reference to an array of boolean values; Logical true value indicates that this column may contain "NULL"'s.

NUM_OF_FIELDS

Number of fields returned by a "SELECT" statement. You may use this for checking whether a statement returned a result: A zero value indicates a non-"SELECT" statement like "INSERT", "DELETE" or "UPDATE".

mariadb_table

A reference to an array of table names, useful in a "JOIN" result.

TYPE

A reference to an array of column types. The engine's native column types are mapped to portable types like "DBI::SQL_INTEGER()" or "DBI::SQL_VARCHAR()", as good as possible. Not all native types have a meaningful equivalent. If you need the native column types, use mariadb_type. See below.

mariadb_type

A reference to an array of MySQL's native column types, for example "DBD::MariaDB::TYPE_SHORT()" or "DBD::MariaDB::TYPE_STRING()". Use the TYPE attribute, if you want portable types like "DBI::SQL_SMALLINT()" or "DBI::SQL_VARCHAR()".

mariadb_type_name

Similar to mariadb_type, but type names and not numbers are returned. Whenever possible, the ANSI SQL name is preferred.

mariadb_warning_count

The number of warnings generated during execution of the SQL statement. This attribute is available on both statement handles and database handles.

UNICODE SUPPORT

MySQL's "utf8mb4" charset for the network communication is configured by "MYSQL_SET_CHARSET_NAME" libmariadb/libmysqlclient C library API which is a requirement to have working quote method and an emulated client side placeholders replacement.

Do not try to change network charset (e.g. via SQL command "SET NAMES" manually) to anything different then UTF-8 as it would confuse underlying C library and DBD::MariaDB would misbehave (e.g. would lead to broken/insecure quote method or an emulated client side placeholders replacement).

Using a non-UTF-8 charset for a column, table or database is fine because MariaDB or MySQL server automatically transforms the storage charset to the charset used by the network protocol ("utf8mb4"). Note that when DBD::MariaDB is connecting to the MariaDB or MySQL server it calls SQL command "SET character_set_server = 'utf8mb4'" to ensure that the default charset for new databases would be UTF-8. Beware that a default charset for new tables is set from a database charset.

In the case MySQL server does not support MySQL's "utf8mb4" charset for a network protocol then DBD::MariaDB would try to use MySQL's "utf8" charset which is a subset of UTF-8 encoding restricted to the 3 byte UTF-8 sequences. Support for MySQL's "utf8mb4" charset was introduced in MySQL server version 5.5.3.

  # Prepare statement
  my $sth = $dbh->prepare(
      'INSERT INTO users (id, name, picture) VALUES (?, ?, ?)'
  );

  # Bind number, 7-bit ASCII values are always in Unicode and binary context
  $sth->bind_param(1, 10);

  # Bind name, may contains Unicode character, in this case U+00E9
  $sth->bind_param(2, "Andr\x{E9}");

  # Bind picture, it is a sequence of binary bytes, not Unicode code points
  $sth->bind_param(3, "\x{D8}\x{A0}\x{39}\x{F8}", DBI::SQL_BINARY);

  # Execute statement with bind parameters
  $sth->execute();

  my $param1 = 10;
  my $param2 = "Andr\x{E9}";
  my $param3 = "\x{D8}\x{A0}\x{39}\x{F8}";
  my $query = 'INSERT INTO users (id, name, picture) VALUES (' .
                $dbh->quote($param1) . ' ,' .
                $dbh->quote($param2) . ' ,' .
                $dbh->quote($param3, DBI::SQL_BINARY) .
              ')';
  $dbh->do($query);

TRANSACTION SUPPORT

• By default AutoCommit mode is on, following the DBI specifications.
• If you execute

    $dbh->{AutoCommit} = 0;
      

  or

    $dbh->{AutoCommit} = 1;
      

  then the driver will set the MariaDB or MySQL server variable autocommit to 0 or 1, respectively. Switching from 0 to 1 will also issue a "COMMIT", following the DBI specifications.

• The methods

    $dbh->rollback();
    $dbh->commit();
      

  will issue the commands "ROLLBACK" and "COMMIT", respectively. A "ROLLBACK" will also be issued if AutoCommit mode is off and the database handles DESTROY method is called. Again, this is following the DBI specifications.

Given the above, you should note the following:

• You should never change the server variable AutoCommit manually, unless you are ignoring DBI's transaction support.
• Switching AutoCommit mode from on to off or vice versa may fail. You should always check for errors when changing AutoCommit mode. The suggested way of doing so is using the DBI flag RaiseError. If you don't like RaiseError, you have to use code like the following:

    $dbh->{AutoCommit} = 0;
    if ($dbh->{AutoCommit}) {
        # An error occurred!
    }
      

• If you detect an error while changing the AutoCommit mode, you should no longer use the database handle. In other words, you should disconnect and reconnect again, because the transaction mode is unpredictable. Alternatively you may verify the transaction mode by checking the value of the server variable autocommit. However, such behaviour isn't portable.
• DBD::MariaDB has a reconnect feature that handles the so-called MySQL morning bug: If the server has disconnected, most probably due to a timeout, then by default the driver will reconnect and attempt to execute the same SQL statement again. However, this behaviour is disabled when AutoCommit is off: Otherwise the transaction state would be completely unpredictable after a reconnect.
• The reconnect feature of DBD::MariaDB can be toggled by using the mariadb_auto_reconnect attribute. This behaviour should be turned off in code that uses LOCK TABLE because if the database server time out and DBD::MariaDB reconnect, table locks will be lost without any indication of such loss.

MULTIPLE RESULT SETS

The basic usage of multiple result sets is

  do {
      while (my @row = $sth->fetchrow_array()) {
          do stuff;
      }
  } while ($sth->more_results);

An example would be:

  $dbh->do('drop procedure if exists someproc')
      or print $DBI::errstr;

  $dbh->do('create procedure someproc() deterministic
      begin
          declare a,b,c,d int;
          set a=1;
          set b=2;
          set c=3;
          set d=4;
          select a, b, c, d;
          select d, c, b, a;
          select b, a, c, d;
          select c, b, d, a;
      end'
  ) or die "$DBI::err: $DBI::errstr";

  my $sth = $dbh->prepare('call someproc()')
      or die "$DBI::err: $DBI::errstr";

  $sth->execute()
      or die "$DBI::err: $DBI::errstr";

  my $i=0;
  do {
      print "\nRowset ".++$i."\n---------------------------------------\n\n";
      foreach my $colno (0..$sth->{NUM_OF_FIELDS}-1) {
          print $sth->{NAME}->[$colno]."\t";
      }
      print "\n";
      while (my @row = $sth->fetchrow_array())  {
          foreach $field (0..$#row) {
              print $row[$field]."\t";
          }
          print "\n";
      }
  } while ($sth->more_results);

MULTITHREADING

The obvious question is: Are the C libraries thread safe? In the case of MySQL the answer is yes, since MySQL 5.5 it is. Older versions C library needs to be compiled with "--with-thread-safe-client" or "--enable-thread-safe-client" configure options.

ASYNCHRONOUS QUERIES

Here's an example of how to use the asynchronous query interface:

  use feature 'say';
  $dbh->do('SELECT SLEEP(10)', { mariadb_async => 1 });
  until($dbh->mariadb_async_ready()) {
      say 'not ready yet!';
      sleep 1;
  }
  my $rows = $dbh->mariadb_async_result();

INSTALLATION

AUTHORS

The first incarnation of DBD::mysql was developed by Alligator Descartes, who was also aided and abetted by Gary Shea, Andreas König and Tim Bunce.

The current incarnation of DBD::mysql was written by Jochen Wiedmann, then numerous changes and bug-fixes were added by Rudy Lippan. Next, prepared statement support was added by Patrick Galbraith and Alexy Stroganov (who also solely added embedded server support).

Since 2004 DBD::mysql has been maintained by Patrick Galbraith (patg@patg.net), and since 2013 with the great help of Michiel Beijen (michiel.beijen@gmail.com), along with the entire community of Perl developers who keep sending patches to help continue improving DBD::mysql.

In 2018 unreleased version 4.042_01 of DBD::mysql was forked and DBD::MariaDB was created to fix long standing Unicode bugs and MariaDB support. Currently it is developed in GoodData and maintained by Pali (pali@cpan.org).

CONTRIBUTIONS

<https://github.com/gooddata/DBD-MariaDB>

Either fork this repository and produce a branch with your changeset that the maintainer can merge to his tree, or create a diff with git. The maintainer is more than glad to take contributions from the community as many features and fixes from DBD::MariaDB have come from the community.

COPYRIGHT

• Large Portions Copyright (c) 2018 GoodData Corporation
• Large Portions Copyright (c) 2015-2017 Pali Rohár
• Large Portions Copyright (c) 2004-2017 Patrick Galbraith
• Large Portions Copyright (c) 2013-2017 Michiel Beijen
• Large Portions Copyright (c) 2004-2007 Alexey Stroganov
• Large Portions Copyright (c) 2003-2005 Rudolf Lippan
• Large Portions Copyright (c) 1997-2003 Jochen Wiedmann, with code portions
• Copyright (c)1994-1997 their original authors

LICENSE

MAILING LIST SUPPORT

To subscribe to this list, send an email to

"dbi-users-subscribe@perl.org" <mailto:dbi-users-subscribe@perl.org>

Mailing list archives are at

<http://groups.google.com/group/perl.dbi.users?hl=en&lr=>

ADDITIONAL DBI INFORMATION

<http://dbi.perl.org>

where documentation, pointers to the mailing lists and mailing list archives and pointers to the most current versions of the modules can be used.

Information on the DBI interface itself can be gained by typing:

  perldoc DBI

Information on DBD::MariaDB specifically can be gained by typing:

  perldoc DBD::MariaDB

(this will display the document you're currently reading)

BUG REPORTING, ENHANCEMENT/FEATURE REQUESTS

<https://github.com/gooddata/DBD-MariaDB/issues>

In past for DBD::mysql, MySQL/Sun/Oracle responded to bugs and assisted in fixing bugs which many thanks should be given for their help! This driver is outside the realm of the numerous components they support, and the maintainer and community solely support DBD::mysql and DBD::MariaDB.