NAME

MARC::Field - Perl extension for handling MARC fields

SYNOPSIS

  use MARC::Field;

  # If your system uses wacky control field tags, add them
  MARC::Field->allow_controlfield_tags('FMT', 'LLE');

  my $field = MARC::Field->new( 245, '1', '0',
       'a' => 'Raccoons and ripe corn / ',
       'c' => 'Jim Arnosky.'
  );
  $field->add_subfields( "a", "1st ed." );

DESCRIPTION

Defines MARC fields for use in the MARC::Record module. I suppose you could use them on their own, but that wouldn't be very interesting.

EXPORT

None by default. Any errors are stored in $MARC::Field::ERROR, which $MARC::Record usually bubbles up to $MARC::Record::ERROR.

CLASS VARIABLES

extra_controlfield_tags: Some systems (notably Ex Libris's Aleph) throw extra control fields in their MARC (e.g., Aleph's MARC-XML tends to have a "FMT" control field). We keep a class-level hash to track to track them; it can be manipulated with "allow_controlfield_tags" and c<disallow_controlfield_tags>.

METHODS

new()

The constructor, which will return a MARC::Field object. Typically you will pass in the tag number, indicator 1, indicator 2, and then a list of any subfield/data pairs. For example:

  my $field = MARC::Field->new(
       245, '1', '0',
       'a' => 'Raccoons and ripe corn / ',
       'c' => 'Jim Arnosky.'
  );

Or if you want to add a control field (< 010) that does not have indicators.

  my $field = MARC::Field->new( '001', ' 14919759' );

tag()

Returns the three digit tag for the field.

set_tag(tag)

Changes the tag number of this field. Updates the control status accordingly. Will "croak" if an invalid value is passed in.

indicator(indno)

Returns the specified indicator. Returns "undef" and logs a warning if field is a control field and thus doesn't have indicators. If the field is not a control field, croaks if the indno is not 1 or 2.

set_indicator($indno, $indval)

Set the indicator position $indno to the value specified by $indval. Croaks if the indicator position, is invalid, the field is a control field and thus doesn't have indicators, or if the new indicator value is invalid.

allow_controlfield_tags($tag, $tag2, ...)

Add $tags to class-level list of strings to consider valid control fields tags (in addition to 001 through 009). Tags must have three characters.

disallow_controlfield_tags($tag, $tag2, ...) =head2 disallow_controlfield_tags('*')

Revoke the validity of a control field tag previously added with allow_controlfield_tags. As a special case, if you pass the string '*' it will clear out all previously-added tags.

NOTE that this will only deal with stuff added with allow_controlfield_tags; you can't disallow '001'.

is_valid_tag($tag) -- is the given tag valid?

Generally called as a class method (e.g., MARC::Field->is_valid_tag('001'))

is_valid_indicator($indval) -- is the given indicator value valid?

Generally called as a class method (e.g., MARC::Field->is_valid_indicator('4'))

is_controlfield_tag($tag) -- does the given tag denote a control field?

Generally called as a class method (e.g., MARC::Field->is_controlfield_tag('001'))

is_control_field()

Tells whether this field is one of the control tags from 001-009.

subfield(code)

When called in a scalar context returns the text from the first subfield matching the subfield code.

    my $subfield = $field->subfield( 'a' );

Or if you think there might be more than one you can get all of them by calling in a list context:

    my @subfields = $field->subfield( 'a' );

If no matching subfields are found, "undef" is returned in a scalar context and an empty list in a list context.

If the tag is a control field, "undef" is returned and $MARC::Field::ERROR is set.

subfields()

Returns all the subfields in the field. What's returned is a list of list refs, where the inner list is a subfield code and the subfield data.

For example, this might be the subfields from a 245 field:

        (
          [ 'a', 'Perl in a nutshell :' ],
          [ 'b', 'A desktop quick reference.' ],
        )

data()

Returns the data part of the field, if the tag number is less than 10.

add_subfields(code,text[,code,text ...])

Adds subfields to the end of the subfield list.

    $field->add_subfields( 'c' => '1985' );

Returns the number of subfields added, or "undef" if there was an error.

delete_subfield()

delete_subfield() allows you to remove subfields from a field:

    # delete any subfield a in the field
    $field->delete_subfield(code => 'a');

    # delete any subfield a or u in the field
    $field->delete_subfield(code => ['a', 'u']);

    # delete any subfield code matching a compiled regular expression
    $field->delete_subfield(code => qr/[^a-z0-9]/);

If you want to only delete subfields at a particular position you can use the pos parameter:

    # delete subfield u at the first position
    $field->delete_subfield(code => 'u', pos => 0);

    # delete subfield u at first or second position
    $field->delete_subfield(code => 'u', pos => [0,1]);

    # delete the second subfield, no matter what it is
    $field->delete_subfield(pos => 1);

You can specify a regex to for only deleting subfields that match:

   # delete any subfield u that matches zombo.com
   $field->delete_subfield(code => 'u', match => qr/zombo.com/);

   # delete any subfield that matches quux
   $field->delete_subfield(match => qr/quux/);

You can also pass a single subfield label:

  # delete all subfield u
  $field->delete_subfield('u');

delete_subfields()

Delete all subfields with a given subfield code. This is here for backwards compatibility, you should use the more flexible delete_subfield().

update()

Allows you to change the values of the field. You can update indicators and subfields like this:

  $field->update( ind2 => '4', a => 'The ballad of Abe Lincoln');

If you attempt to update a subfield which does not currently exist in the field, then a new subfield will be appended to the field. If you don't like this auto-vivification you must check for the existence of the subfield prior to update.

  if ( $field->subfield( 'a' ) ) {
    $field->update( 'a' => 'Cryptonomicon' );
  }

If you want to update a field that has no indicators or subfields (000-009) just call update() with one argument, the string that you would like to set the field to.

  $field = $record->field( '003' );
  $field->update('IMchF');

Note: when doing subfield updates be aware that "update()" will only update the first occurrence. If you need to do anything more complicated you will probably need to create a new field and use "replace_with()".

Returns the number of items modified.

replace_with()

Allows you to replace an existing field with a new one. You need to pass "replace()" a MARC::Field object to replace the existing field with. For example:

  $field = $record->field('245');
  my $new_field = new MARC::Field('245','0','4','The ballad of Abe Lincoln.');
  $field->replace_with($new_field);

Doesn't return a meaningful or reliable value.

as_string( [$subfields] [, $delimiter] )

Returns a string of all subfields run together. A space is added to the result between each subfield, unless the delimiter parameter is passed. The tag number and subfield character are not included.

Subfields appear in the output string in the order in which they occur in the field.

If $subfields is specified, then only those subfields will be included.

  my $field = MARC::Field->new(
                245, '1', '0',
                        'a' => 'Abraham Lincoln',
                        'h' => '[videorecording] :',
                        'b' => 'preserving the union /',
                        'c' => 'A&E Home Video.'
                );
  print $field->as_string( 'abh' ); # Only those three subfields
  # prints 'Abraham Lincoln [videorecording] : preserving the union /'.
  print $field->as_string( 'ab', '--' ); # Only those two subfields, with a delimiter
  # prints 'Abraham Lincoln--preserving the union /'.

Note that subfield h comes before subfield b in the output.

as_formatted()

Returns a pretty string for printing in a MARC dump.

as_usmarc()

Returns a string for putting into a USMARC file. It's really only useful for "MARC::Record::as_usmarc()".

clone()

Makes a copy of the field. Note that this is not just the same as saying

    my $newfield = $field;

since that just makes a copy of the reference. To get a new object, you must

    my $newfield = $field->clone;

Returns a MARC::Field record.

warnings()

Returns the warnings that were created when the record was read. These are things like "Invalid indicators converted to blanks".

The warnings are items that you might be interested in, or might not. It depends on how stringently you're checking data. If you're doing some grunt data analysis, you probably don't care.

TODO

See the "TODO" section for MARC::Record.

LICENSE

This code may be distributed under the same terms as Perl itself.

Please note that these modules are not products of or supported by the employers of the various contributors to the code.

AUTHOR

Andy Lester, "<andy@petdance.com>"