Class::MakeMethods Calling Conventions

You can also omit the arguments to "use" and instead make methods at runtime by passing the declarations to a subsequent call to "make()".

You may include any number of declarations in each call to "use" or "make()". If methods with the same name already exist, earlier calls to "use" or "make()" win over later ones, but within each call, later declarations superceed earlier ones.

You can install methods in a different package by passing "-TargetClass => package" as your first arguments to "use" or "make".

See Class::MakeMethods for more details.

Passing Parameters

• generator_type => "method_name"
• generator_type => "name_1 name_2..."
• generator_type => [ "name_1", "name_2", ...]

See "TEMPLATE CLASSES" in Class::MakeMethods::Docs::Catalog for a list of the supported values of generator_type.

For each method name you provide, a subroutine of the indicated type will be generated and installed under that name in your module.

Method names should start with a letter, followed by zero or more letters, numbers, or underscores.

Standard Declaration Syntax

• generator_type => [ "name_1" => { param=>value... }, ... ]

  A hash of parameters to use just for this method name.

  (Note: to prevent confusion with self-contained definition hashes, described below, parameter hashes following a method name must not contain the key 'name'.)

• generator_type => [ [ "name_1", "name_2", ... ] => { param=>value... } ]

  Each of these method names gets a copy of the same set of parameters.

• generator_type => [ { "name"=>"name_1", param=>value... }, ... ]

  By including the reserved parameter "name", you create a self contained declaration with that name and any associated hash values.

Basic declarations, as described above, are treated as having an empty parameter hash.

Default Parameters

• '-param' => 'value'

  Set a default value for the specified parameter.

• '--' => { 'param' => 'value', ... }

  Set default values for one or more parameters. Equivalent to a series of '-param' => 'value' pairs for each pair in the referenced hash.

• '--special_param_value'

  Specifies a value for special parameter; the two supported parameter types are:

Parameters set in these ways are passed to each declaration that follows it until the end of the method-generator argument array, or until overridden by another declaration. Parameters specified in a hash for a specific method name, as discussed above, will override the defaults of the same name for that particular method.

Special Parameters

• name

  The primary name of the meta-method. Note that the subroutines installed into the calling package may be given different names, depending on the rules specified by the interface.

• interface

  The name of a predefined interface, or a reference to a custom interface, to use for this meta-method. See "Selecting Interfaces", below.

• modifier

  The names of one or more predefined modifier flags. See "Selecting Modifiers", below.

Informative Parameters

• target_class

  The class that requested the meta-method, into which its subroutines will be installed.

• template_name

  The Class::MakeMethods::Template method used for this declaration.

• template_class

  The Class::MakeMethods::Template subclass used for this declaration.

Other Parameters

Note that you generally should not arbitrarily assign additional parameters to a meta-method unless you know that they do not conflict with any parameters already defined or used by that meta-method.

Parameter Expansion

Example: The following defines counter (*, *_incr, *_reset) meta-methods j and k, which use the hash keys j_index and k_index to fetch and store their values.

  use Class::MakeMethods::Template::Hash
    counter => [ '-hash_key' => '*_index', qw/ j k / ];

(See Class::MakeMethods::Template::Hash for information about the "hash_key" parameter.)

If a parameter specification contains '*{param}', it is replaced with the value of that parameter.

Example: The following defines a Hash scalar meta-method which will store its value in a hash key composed of the defining package's name and individual method name, such as "$self->{ MyObject- foo}":

  use Class::MakeMethods::Template::Hash
    'scalar' => [ '-hash_key' => '*{target_class}-*{name}', qw/ l / ];

Selecting Interfaces

An interface may be specified for a single method by providing an 'interface' parameter:

• 'interface_name'

  Select a predefined interface.

  Example: Instead of the normal Hash scalar method named x, the following creates methods with "Java-style" names and behaviors, getx and setx.

    use Class::MakeMethods::Template::Hash
      'scalar' => [ 'x' => { interface=>'java' } ];
      

  (See "scalar" in Class::MakeMethods::Template::Generic for a description of the "java" interface.)

• 'behavior_name'

  A simple interface consisting only of the named behavior.

  For example, the below declaration creates a read-only methods named q. (There are no set or clear methods, so any value would have to be placed in the hash by other means.)

    use Class::MakeMethods::Template::Hash (
      'scalar' => [ 'q' => { interface=>'get' } ] 
    );
      

• { 'subroutine_name_pattern' => 'behavior_name', ... }

  A custom interface consists of a hash-ref that maps subroutine names to the associated behaviors. Any "*" characters in subroutine_name_pattern are replaced with the declared method name.

  For example, the below delcaration creates paired get_w and set_w methods:

    use Class::MakeMethods::Template::Hash (
      'scalar' => [ 'w' => { interface=> { 'get_*'=>'get', 'set_*'=>'set' } } ] 
    );
      

Some interfaces provide very different behaviors than the default interface.

Example: The following defines a method g, which if called with an argument appends to, rather than overwriting, the current value:

  use Class::MakeMethods::Template::Hash
    'string' => [ '--get_concat', 'g' ];

A named interface may also be specified as a default in the argument list with a leading '--' followed by the interface's name.

Example: Instead of the normal Hash scalar methods (named x and clear_x), the following creates methods with "Java-style" names and behaviors (getx, setx).

  use Class::MakeMethods::Template::Hash
    'scalar' => [ '--java', 'x'  ];

An interface set in this way affects all meta-methods that follow it until another interface is selected or the end of the array is reached; to return to the original names request the 'default' interface.

Example: The below creates "Java-style" methods for e and f, "normal scalar" methods for g, and "Eiffel-style" methods for h.

  use Class::MakeMethods::Template::Hash
    'scalar' => [
      '--java'=> 'e', 'f', 
      '--default'=> 'g', 
      '--eiffel'=> 'h',
    ];

Selecting Modifiers

  use Class::MakeMethods::Template::Hash
      'scalar' => [ 'a', '--protected' => 'b', --private' => 'c' ];

Method b croaks if it's called from outside of the current package or its subclasses.

Method c croaks if it's called from outside of the current package.

See the documentation for each template to learn which modifiers it supports.

Runtime Parameter Access

Example: The following defines a counter meta-method named y, and then later changes the 'join' parameter for that method at runtime.

  use Class::MakeMethods ( get_concat => 'y' );
  
  y_attributes(undef, 'join', "\t" )
  print y_attributes(undef, 'join')

Mechanisms

Class::MakeMethods::Template uses both of these approaches: To generate different types of subroutines, a simple text-substitution mechanism combines bits of Perl to produce the source code for a subroutine, and then evals those to produce code refs. Any differences which can be handled with only data changes are managed at the closure layer; once the subroutines are built, they are repeatedly bound as closures to hashes of parameter data.

Code Generation

There are numerous examples of this within the Generic interface and its subclasses; for examples, look at the following methods: Universal:generic, Generic:scalar, Hash:generic, and Hash:scalar.

See Class::MakeMethods::Utility::TextBuilder for more information.

Template Definitions

Each "use" of your subclass, or call to its "make", causes these objects to assemble the requested methods and return them to Class::MakeMethods for installation in the calling package.

Method generators defined this way will have support for parameters, custom interfaces, and the other features discussed above.

(Your module may also use the "Aliasing" and "Rewriting" functionality described in "EXTENDING" in Class::MakeMethods.)

Definition hashes contain several types of named resources in a second level of hash-refs under the following keys:

• interface - Naming styles (see "Defining Interfaces", below)
• params - Default parameters for meta-methods declared with this template (see "Default Parameters", below)
• behavior - Method recipes (see "Defining Behaviors", below)
• code_expr - Bits of code used by the behaviors

Minimum Template Definition

Class::MakeMethods will automatically fill in the template name and class as 'template_name' and 'template_class' entries in the version of your template definition hash that it caches and uses for future execution.

For example a simple sub-class that defines a method type upper_case_get_set might look like this:

  package Class::MakeMethods::UpperCase;
  use Class::MakeMethods '-isasubclass';
  
  sub uc_scalar {
    return { 
      'behavior' => {
        'default' => sub { 
          my $m_info = $_[0]; 
          return sub {
            my $self = shift;
            if ( scalar @_ ) { 
              $self->{ $m_info->{'name'} } = uc( shift ) 
            } else {
              $self->{ $m_info->{'name'} };
            }
          }
        },
      }
    }
  }

And a caller could then use it to generate methods in their package by invoking:

  Class::MakeMethods::UpperCase->make( 'uc_scalar' => [ 'foo' ] );

Default Parameters

Template-default parameters can be overrridden by interface '-params', described below, and and method-specific parameters, described above.

Defining Interfaces

Most commonly, an interface is specified as a hash which maps one or more subroutine names to the behavior to use for each. The interface subroutine names generally contain an asterisk character, '*', which will be replaced by the name of each meta-method.

Example: The below defines methods e_get, e_set, and e_clear.

  use Class::MakeMethods::Template::Hash
    'scalar' => [
      -interface=>{ '*_clear'=>clear, '*_get'=>'get', '*_set'=>'set' }, 'e' 
    ];

If the provided name does not contain an asterisk, it will not be modified for individual meta-methods; for examples, see the bit_fields method generated by Generic bits, and the DESTROY method generated by InsideOut meta-methods.

In addition to the name-to-behavior correspondences described above, interfaces may also contain additional entries with keys begining with the '-' character which are interpreted as follows:

• "-params => hash_ref"

  Interfaces may include a '-params' key and associated reference to a hash of default parameters for that interface.

• "-base => interface_name"

  Interfaces can be based on previously existing ones by including a -base specification in the the hash. The base value should contain one or more space-separated names of the interfaces to be included.

  Example: The below defines methods getG, setG, and clearG.

    use Class::MakeMethods::Template::Hash
      'scalar' => [
        -interface => { -base=>'java', 'clear*'=>'clear' }, qw/ G / 
      ];
      

  If multiple interfaces are included in the -base specification and specify different behaviors for the same subroutine name, the later ones will override the earlier. Names which appear in the base interface can be overridden by providing a new value, or a name can be removed by mapping it to undef or the empty string.

  Example: The following defines a get-set meta-method h, but supresses the clear_h method:

    use Class::MakeMethods::Template::Hash
      'scalar' => [
        -interface => { -base=>'with_clear', 'clear_*'=>'' }, qw/ h / 
      ];
      

Defining Behaviors

      'behavior' => {
        'default' => q{
            if ( scalar @_ ) { $self->{ $m_info->{'name'} } = uc shift }
            $self->{ $m_info->{'name'} };
        },
      }

A simple substitution syntax provides for macro interpretation with definition strings. This functionality is currently undocumented; for additional details see the _interpret_text_builder function in Class::MakeMethods, and review the code_expr hashes defined in Class::MakeMethods::Generic.

Importing

Inside an -import hash, provide "TemplateClass:type" names for each source you wish to copy from, and the values to import, which can be a string, a reference to an array of strings, or '*' to import everything available. (The order of copying is not defined.)

Example: The below definition creates a new template which is identical to an existing one.

  package Class::MakeMethods::MyMethods;
  sub scalarama {
    { -import => { 'Template::Hash:scalar' => '*' } }
  }

Values that are already set are not modified, unless they're an array ref, in which case they're added to.

Example:

  package Class::MakeMethods::MyMethods;
  sub foo_method {
    { 'behavior' => {
      '-init' => [ sub {  warn "Defining foo_method $_[0]->{'name'}" } ],
      'default' => q{ warn "Calling foo_method behavior" }.
    } }
  }
  sub bar_method {
    { 'behavior' => {
      -import => { 'MyMethods:foo_method' => '*' },
      '-init' => [ sub {  warn "Defining bar_method $_[0]->{'name'}" } ],
      'default' => q{ warn "Calling bar_method behavior" }.
    } }
  }

In this case, the bar_method ends up with an array of two '-init' subroutines, its own and the imported one, but only its own default behavior.

Modifying Existing Templates

Example: The following extends the Hash:scalar template definition by adding a new interface, and then uses it to create scalar accessor methods named access_p and access_q that get and set values for the hash keys 'p' and 'q':

  Class::MakeMethods::Template::Hash->named_method('scalar')->
          {'interface'}{'frozzle'} = { 'access_*'=>'get_set' };

  package My::Object;
  Class::MakeMethods::Template::Hash->make( 'scalar' => [ --frozzle => qw( p q ) ] );

  $object->access_p('Potato');    # $object->{p} = 'Potato'
  print $object->access_q();      # print $object->{q}

Note that this constitutes "action at a distance" and will affect subsequent use by other packages; unless you are "fixing" the current behavior, you are urged to create your own template definition which imports the base behavior of the existing template and overrides the information in question.

Example: The following safely declares a new version of Hash:scalar with the desired additional interface:

  package My::Methods;
  
  sub scalar {
    { 
      -import => { 'Template::Hash:scalar' => '*' } ,
      interface => { 'frozzle' => { 'access_*'=>'get_set' } },
    }
  }

  package My::Object;
  My::Methods->make( 'scalar' => [ --frozzle => qw( p q ) ] );

Disk Caching

  use Class::MakeMethods::Utility::DiskCache qw( /my/code/dir );

This has a mixed effect on performance, but has the notable advantage of letting you view the subroutines that are being generated by your templates.

See Class::MakeMethods::Utility::DiskCache for more information.