"myself()"

Syntax: "myself(@_)"

If your subroutine has been called as an object method, a reference to the object will be returned. If your subroutine has been called as a class method, the name of class itself will be returned as a string. Otherwise, a value of undef is returned.

"OOorNO()"

Syntax: "OOorNO(@_)"

If your subroutine has been called as an object method or as a class method, a value of 1 will be returned, otherwise a false value (an empty string, eg- '') will be returned.

"myargs()"

Syntax: "myargs(@_)"

This method retrieves the input sent to your class methods and returns it untouched, with the exception that if a blessed object reference from the same namespace as the caller is found in $_[0], it will be not be included with the rest of the arguments when they are returned. Make note that the special variable "@_" for your routine is not altered in any way by calling this method. You can still use and manipulate it as you normally would.

Purpose of "OOorNO::myargs"

This simply allows the methods in your class to get their argment list quickly without having to check if they were called procedurally or with object-oriented notation.

   package Your::Class;
   use Class::OOorNO qw( myargs );

   sub bar {

      my(@args) = myargs(@_);
   ...

   package Your::Class;
   use Class::OOorNO;
   our($onobj) = Class::OOorNO->new();

   sub foo {

      my(@args) = $onobj->myargs(@_);
   ...

"coerce_array()"

Syntax: "coerce_array(@array/(list))"

This method retrieves input sent to your class methods when called with name-value pairs and returns an anonymous hash reference whose keys and values correspond to the input argument names and their respective values. If nothing is passed to it, an empty hash reference will be returned, eg- "{ }"

   package Your::Class;
   use Class::OOorNO qw( coerce_array );

   sub bar {

      my($args) = coerce_array(@_);
   ...
    

-OR-

   package Your::Class;
   use Class::OOorNO;
   our($onobj) = Class::OOorNO->new();

   sub foo {

      my($self) = shift(@_);
      my($args) = $onobj->coerce_array(@_);
   ...
    

-OR-

   package Your::Class;
   use Class::OOorNO;
   use vars qw( @ISA );

   @ISA = qw( Class::OOorNO );

   sub foo {

      my($self) = shift(@_);
      my($args) = $self->coerce_array(@_);
   ...
    

Purpose of "OOorNO::coerce_array"

It's common practice for Perl modules to accept name-value pairs for their methods, and because @_ is an array it is easy to encounter warnings and errors when this isn't handled correctly. An example of what this kind of call would look like is shown below in the imaginary subroutine "Your::Class::method()"

   Your::Class->method
      (
         -name => 'Joe',
         -rank => 'Private, First-Class',
         -SN   => '87D91-35-713FOO',
      );
    

"shave_opts()"

Syntax: "shave_opts(\@_)"

-- Documentation for this method is not yet complete! --

using "OOorNO()"

   package Your::Module;
   use strict;
   use Exporter;
   use vars qw( @EXPORT_OK );
   @EXPORT_OK = qw( show_call_style );

   use Class::OOorNO qw( OOorNO );

   sub new { bless { }, shift }

   sub show_call_style {

      if (ref OOorNO(@_)) {
         print __PACKAGE__ . "::foo was called as an OBJECT METHOD.\n"
      }
      elsif (OOorNO(@_)) {
         print __PACKAGE__ . "::foo was called as an CLASS METHOD.\n"
      }
      else {
         print __PACKAGE__ . "::foo was called as a SUBROUTINE.\n"
      }
   }

User's code...

   package main;
   use strict;
   use Your::Module qw( show_call_style );

   my($YM) = Your::Module->new;

   $YM->show_call_style;            # as an object method
   Your::Module->show_call_style;   # as a class method
   &Your::Module::show_call_style;  # as a subroutine
   &show_call_style;                # as imported subroutine

Output:

   Your::Module::foo was called as an OBJECT METHOD.
   Your::Module::foo was called as an CLASS METHOD.
   Your::Module::foo was called as a SUBROUTINE.
   Your::Module::foo was called as a SUBROUTINE.

using "myself()"

   package Your::Module;
   use strict;
   use Exporter;
   use vars qw( @EXPORT_OK );
   @EXPORT_OK = qw( print_self_name );

   use Class::OOorNO qw( myself );

   sub new { bless { }, shift }

   sub print_self_name {
      print( (ref myself(@_) || myself(@_) || __PACKAGE__), "\n" )
   }

User's code...

   package main;
   use strict;
   use Your::Module qw( print_self_name );

   my($YM) = Your::Module->new;

   $YM->print_self_name;            # as an object method
   Your::Module->print_self_name;   # as a class method
   &Your::Module::print_self_name;  # as a subroutine
   print_self_name;                 # as imported subroutine

Output:

   Your::Module
   Your::Module
   Your::Module
   Your::Module

Your module...

   package Your::Module;
   use strict;
   use Exporter;
   use vars qw( @EXPORT_OK );
   @EXPORT_OK = qw( show_call_style   get_self_ref );

   use Class::OOorNO qw( OOorNO   myself );

   sub new { bless { }, shift }

   sub show_call_style {

      if (ref OOorNO(@_)) {
         print __PACKAGE__ . "::foo was called as an OBJECT METHOD.\n"
      }
      elsif (OOorNO(@_)) {
         print __PACKAGE__ . "::foo was called as an CLASS METHOD.\n"
      }
      else {
         print __PACKAGE__ . "::foo was called as a SUBROUTINE.\n"
      }
   }

   sub get_self_ref {
      ref myself(@_) ? myself(@_) : __PACKAGE__->new
   }

User's code...

   package main;
   use strict;
   use Your::Module qw( show_call_style   get_self_ref );

   my($YM) = Your::Module->new;

   # supports calls that go way down the stack too:
   Your::Module->new->get_self_ref->show_call_style;
   Your::Module->get_self_ref->show_call_style;
   &Your::Module::get_self_ref->show_call_style;
   get_self_ref->show_call_style;

Output:

   Your::Module::foo was called as an OBJECT METHOD.
   Your::Module::foo was called as an OBJECT METHOD.
   Your::Module::foo was called as an OBJECT METHOD.
   Your::Module::foo was called as an OBJECT METHOD.

using "myargs()"

   package Your::Module;
   use strict;
   use Exporter;
   use vars qw( @EXPORT_OK );
   @EXPORT_OK = qw( print_argument_list );

   use Class::OOorNO qw( myargs );

   sub new { bless { }, shift }

   sub print_argument_list {
      print "My argument list: \n" . join("\n", myargs(@_)), "\n";
   }

User's code...

   package main;
   use strict;
   use Your::Module qw( print_argument_list );

   my($YM) = Your::Module->new;

   my(@things) = (   'foo',
                     12687.357,
                     $YM,
                     eval('*bar'),
                     [ 'baz', sub { "wubble" },
                     { 'flarp' => 'wibble' } ]   );

   $YM->print_argument_list(@things);           # as an object method
   Your::Module->print_argument_list(@things);  # as a class method
   &Your::Module::print_argument_list(@things); # as a subroutine
   print_argument_list(@things);                # as imported subroutine

Output:

   My argument list:
   foo
   12687.357
   Your::Module=HASH(0x9bd858)
   *main::bar
   ARRAY(0x9bd954)

      ...repeated four times

using "coerce_array()"

   package Your::Module;
   use strict;
   use Exporter;
   use vars qw( @EXPORT_OK );
   @EXPORT_OK = qw( pass_name_value_pairs );

   use Class::OOorNO qw( coerce_array );

   sub new { bless { }, shift }

   sub pass_name_value_pairs {
      my($input)  = coerce_array(@_);

      my($driver) = $input->{'-driver'} || 'nobody';
      my($car)    = $input->{'-car'}    || 'no car';
      my($bike)   = $input->{'-bike'}   || 'no bike';
      my($plane)  = $input->{'-plane'}  || 'no plane';

      print("$driver drives $car, $bike, and $plane.\n");
   }

User's code...

Output:

using "shave_opts()"

   package Your::Module;
   use strict;
   use Exporter;
   use vars qw( @EXPORT_OK );
   @EXPORT_OK = qw( print_options );

   use Class::OOorNO qw( shave_opts );

   sub new { bless { }, shift }

   sub print_options {
      my($opts) = shave_opts(\@_);
      print "\n",
      ( map { qq[$_ => $opts->{$_}] . "\n" } keys %$opts ),
      "\n"
   }

User's code...

Output: